Rules for integrands of the form  u ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)

1:  ∫u ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  when  b c-a d==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If b c-a d==0, then a+b x==(b/d)(c+d x)

Rule: If  b c-a d==0 ∧ p∈ℤ, then

∫u ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  ⟶  ∫u ((Log[e ((((((b^p) f)/(d^p)) (((c+d x))^(p+q))))^r)])^s) dx

Program code:

Int[u_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  Int[u*Log[e*(b^p*f/d^p*(c+d*x)^(p+q))^r]^s,x] /;
FreeQ[{a,b,c,d,e,f,p,q,r,s},x] && EqQ[b*c-a*d,0] && IntegerQ[p]

2.  ∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  when  b c-a d≠0

2:  ∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s) dx  when  b c-a d≠0 ∧ p+q≠0 ∧ s∈(SuperPlus[ℤ])∧ s<4

Derivation: Integration by parts

Basis: 1==(∂_x)((a+b x)/b)

Basis: (∂_x)((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)==((b r s (p+q) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/(a+b x))-((q r s (b c-a d) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/((a+b x) (c+d x)))

Rule: If  b c-a d≠0 ∧ p+q≠0 ∧ s∈(SuperPlus[ℤ])∧ s<4, then

∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s) dx  ⟶  

(((a+b x) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/b)-
r s (p+q) ∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))dx+((q r s (b c-a d))/b) ∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))/(c+d x))dx

Program code:

Int[Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  (a+b*x)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s/b - 
  r*s*(p+q)*Int[Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1),x] + 
  q*r*s*(b*c-a*d)/b*Int[Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1)/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,p,q,r,s},x] && NeQ[b*c-a*d,0] && NeQ[p+q,0] && IGtQ[s,0] && LtQ[s,4]

3.  ∫(((g+h x))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  when  b c-a d≠0

2.  ∫(((g+h x))^m) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  when  b c-a d≠0

1:  ∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(g+h x))dx  when  b c-a d≠0

Derivation: Integration by parts

Basis: (1/(g+h x))==(∂_x)((Log[g+h x])/h)

Basis: (∂_x)Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]==((b p r)/(a+b x))+((d q r)/(c+d x))

Rule: If  b c-a d≠0, then

∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(g+h x))dx  ⟶  

((Log[g+h x] Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/h)-((b p r)/h)∫((Log[g+h x])/(a+b x))dx-((d q r)/h)∫((Log[g+h x])/(c+d x))dx

Program code:

Int[Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]/(g_.+h_.*x_),x_Symbol] :=
  Log[g+h*x]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]/h - 
  b*p*r/h*Int[Log[g+h*x]/(a+b*x),x] - 
  d*q*r/h*Int[Log[g+h*x]/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,p,q,r},x] && NeQ[b*c-a*d,0]

2:  ∫(((g+h x))^m) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  when  b c-a d≠0 ∧ m≠-1

Derivation: Integration by parts

Basis: (((g+h x))^m)==(∂_x)((((g+h x))^(m+1))/(h (m+1)))

Basis: (∂_x)Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]==((b p r)/(a+b x))+((d q r)/(c+d x))

Rule: If  b c-a d≠0 ∧ m≠-1, then

∫(((g+h x))^m) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  ⟶  

(((((g+h x))^(m+1)) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(h (m+1)))-((b p r)/(h (m+1))) ∫((((g+h x))^(m+1))/(a+b x))dx-((d q r)/(h (m+1))) ∫((((g+h x))^(m+1))/(c+d x))dx

Program code:

Int[(g_.+h_.*x_)^m_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.],x_Symbol] :=
  (g+h*x)^(m+1)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]/(h*(m+1)) - 
  b*p*r/(h*(m+1))*Int[(g+h*x)^(m+1)/(a+b*x),x] - 
  d*q*r/(h*(m+1))*Int[(g+h*x)^(m+1)/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,p,q,r},x] && NeQ[b*c-a*d,0] && NeQ[m,-1]

3.  ∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  when  b c-a d≠0

1:  ∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  when  b c-a d≠0 ∧ b g-a h==0

Derivation: Piecewise constant extraction

Basis: (∂_x)(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+b x))^(p r))]-Log[(((c+d x))^(q r))])==0

Rule: If  b c-a d≠0 ∧ b g-a h==0, then

∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  ⟶  

∫((((Log[(((a+bx))^(p r))]+Log[(((c+dx))^(q r))]))^2)/(g+h x))dx+(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+bx))^(p r))]-Log[(((c+dx))^(q r))])·
(2 ∫((Log[(((c+dx))^(q r))])/(g+h x))dx+∫((Log[(((a+bx))^(p r))]-Log[(((c+dx))^(q r))]+Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(g+h x))dx)

Program code:

Int[Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^2/(g_.+h_.*x_),x_Symbol] :=
  Int[(Log[(a+b*x)^(p*r)]+Log[(c+d*x)^(q*r)])^2/(g+h*x),x] + 
  (Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]-Log[(a+b*x)^(p*r)]-Log[(c+d*x)^(q*r)])*
    (2*Int[Log[(c+d*x)^(q*r)]/(g+h*x),x] + 
     Int[(Log[(a+b*x)^(p*r)]-Log[(c+d*x)^(q*r)]+Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r])/(g+h*x),x]) /;
FreeQ[{a,b,c,d,e,f,g,h,p,q,r},x] && NeQ[b*c-a*d,0] && EqQ[b*g-a*h,0]

x:  ∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  when  b c-a d≠0 ∧ b g-a h≠0 ∧ d g-c h≠0    ????

Derivation: Piecewise constant extraction

Basis: (∂_x)(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+b x))^(p r))]-Log[(((c+d x))^(q r))])==0

Rule: If  b c-a d≠0 ∧ b g-a h==0, then

∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  ⟶  

∫((((Log[(((a+bx))^(p r))]+Log[(((c+dx))^(q r))]))^2)/(g+h x))dx+
(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+bx))^(p r))]-Log[(((c+dx))^(q r))])
∫((Log[(((a+bx))^(p r))]+Log[(((c+dx))^(q r))]+Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(g+h x))dx

Program code:

(* Int[Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^2/(g_.+h_.*x_),x_Symbol] :=
  Int[(Log[(a+b*x)^(p*r)]+Log[(c+d*x)^(q*r)])^2/(g+h*x),x] + 
  (Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]-Log[(a+b*x)^(p*r)]-Log[(c+d*x)^(q*r)])*
    Int[(Log[(a+b*x)^(p*r)]+Log[(c+d*x)^(q*r)]+Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r])/(g+h*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,p,q,r},x] && NeQ[b*c-a*d,0] && EqQ[b*g-a*h,0] *)

2:  ∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  when  b c-a d≠0

Derivation: Integration by parts

Basis: (1/(g+h x))==(∂_x)((Log[g+h x])/h)

Basis: (∂_x)((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)==((2 b p r Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(a+b x))+((2 d q r Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(c+d x))

Rule: If  b c-a d≠0, then

∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2)/(g+h x))dx  ⟶  

((Log[g+h x] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^2))/h)-
((2 b p r)/h)∫((Log[g+h x] Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(a+b x))dx-((2 d q r)/h)∫((Log[g+h x] Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(c+d x))dx

Program code:

Int[Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^2/(g_.+h_.*x_),x_Symbol] :=
  Log[g+h*x]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^2/h - 
  2*b*p*r/h*Int[Log[g+h*x]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]/(a+b*x),x] - 
  2*d*q*r/h*Int[Log[g+h*x]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,p,q,r},x] && NeQ[b*c-a*d,0]

4:  ∫(((g+h x))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  when  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ m≠-1

Derivation: Integration by parts

Basis: (((g+h x))^m)==(∂_x)((((g+h x))^(m+1))/(h (m+1)))

Basis: (∂_x)((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)==((b p r s)/(a+b x))((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))+((d q r s)/(c+d x))((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))

Rule: If  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ m≠-1, then

∫(((g+h x))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  ⟶  

(((((g+h x))^(m+1)) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/(h (m+1)))-
((b p r s)/(h (m+1))) ∫(((((g+h x))^(m+1)) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/(a+b x))dx-((d q r s)/(h (m+1))) ∫(((((g+h x))^(m+1)) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/(c+d x))dx

Program code:

Int[(g_.+h_.*x_)^m_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_,x_Symbol] :=
  (g+h*x)^(m+1)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s/(h*(m+1)) - 
  b*p*r*s/(h*(m+1))*Int[(g+h*x)^(m+1)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1)/(a+b*x),x] - 
  d*q*r*s/(h*(m+1))*Int[(g+h*x)^(m+1)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1)/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,p,q,r,s},x] && NeQ[b*c-a*d,0] && IGtQ[s,0] && NeQ[m,-1]

4.  ∫(((((s+t Log[i (((g+h x))^n)]))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^u))/(j+k x))dx  when  b c-a d≠0

1:  ∫(((((s+t Log[i (((g+h x))^n)]))^m) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(j+k x))dx  when  b c-a d≠0 ∧ h j-g k==0 ∧ m∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: If  h j-g k==0, then (((((s+t Log[i (((g+h x))^n)]))^m) )/(j+k x))==(∂_x)((((s+t Log[i (((g+h x))^n)]))^(m+1))/(k n t (m+1)))

Basis: (∂_x)Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]==((b p r)/(a+b x))+((d q r)/(c+d x))

Rule: If  b c-a d≠0 ∧ h j-g k==0 ∧ m∈(SuperPlus[ℤ]), then

∫(((((s+t Log[i (((g+h x))^n)]))^m) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(j+k x))dx  ⟶  

(((((s+t Log[i (((g+h x))^n)]))^(m+1)) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(k n t (m+1)))-
((b p r)/(k n t (m+1))) ∫((((s+t Log[i (((g+h x))^n)]))^(m+1))/(a+b x))dx-((d q r)/(k n t (m+1))) ∫((((s+t Log[i (((g+h x))^n)]))^(m+1))/(c+d x))dx

Program code:

Int[(s_.+t_.*Log[i_.*(g_.+h_.*x_)^n_.])^m_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]/(j_.+k_.*x_),x_Symbol] :=
  (s+t*Log[i*(g+h*x)^n])^(m+1)*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]/(k*n*t*(m+1)) - 
  b*p*r/(k*n*t*(m+1))*Int[(s+t*Log[i*(g+h*x)^n])^(m+1)/(a+b*x),x] - 
  d*q*r/(k*n*t*(m+1))*Int[(s+t*Log[i*(g+h*x)^n])^(m+1)/(c+d*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,s,t,m,n,p,q,r},x] && NeQ[b*c-a*d,0] && EqQ[h*j-g*k,0] && IGtQ[m,0]

2:  ∫(((s+t Log[i (((g+h x))^n)]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(j+k x))dx  when  b c-a d≠0

Derivation: Piecewise constant extraction

Basis: (∂_x)(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+b x))^(p r))]-Log[(((c+d x))^(q r))])==0

Rule: If  b c-a d≠0, then

∫(((s+t Log[i (((g+h x))^n)]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(j+k x))dx  ⟶  

(Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-Log[(((a+b x))^(p r))]-Log[(((c+d x))^(q r))]) ∫(((s+t Log[i (((g+h x))^n)]))/(j+k x))dx+
∫((Log[(((a+b x))^(p r))] (s+t Log[i (((g+h x))^n)]))/(j+k x))dx+∫((Log[(((c+d x))^(q r))] (s+t Log[i (((g+h x))^n)]))/(j+k x))dx

Program code:

Int[(s_.+t_.*Log[i_.*(g_.+h_.*x_)^n_.])*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]/(j_.+k_.*x_),x_Symbol] :=
  (Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]-Log[(a+b*x)^(p*r)]-Log[(c+d*x)^(q*r)])*Int[(s+t*Log[i*(g+h*x)^n])/(j+k*x),x] + 
  Int[(Log[(a+b*x)^(p*r)]*(s+t*Log[i*(g+h*x)^n]))/(j+k*x),x] + 
  Int[(Log[(c+d*x)^(q*r)]*(s+t*Log[i*(g+h*x)^n]))/(j+k*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,s,t,n,p,q,r},x] && NeQ[b*c-a*d,0]

U:  ∫(((((s+t Log[i (((g+h x))^n)]))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^u))/(j+k x))dx  when  b c-a d≠0

Rule: If  b c-a d≠0, then

∫(((((s+t Log[i (((g+h x))^n)]))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^u))/(j+k x))dx  ⟶  ∫(((((s+t Log[i (((g+h x))^n)]))^m) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^u))/(j+k x))dx

Program code:

Int[(s_.+t_.*Log[i_.*(g_.+h_.*x_)^n_.])^m_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^u_./(j_.+k_.*x_),x_Symbol] :=
  Unintegrable[(s+t*Log[i*(g+h*x)^n])^m*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^u/(j+k*x),x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,k,s,t,m,n,p,q,r,u},x] && NeQ[b*c-a*d,0]

6.  ∫((u ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  when  b c-a d≠0 ∧ p+q==0

1:  ∫((Log[1+g((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  when  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ p+q==0

Derivation: Integration by parts

Basis: ((Log[1+g((a+b x)/(c+d x))])/((a+b x) (c+d x)))==-(∂_x)((PolyLog[2,-g((a+b x)/(c+d x))])/(b c-a d))

Basis: If  p+q==0, then (∂_x)((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)==((p r s (b c-a d))/((a+b x) (c+d x))) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))

Rule: If  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ p+q==0, then

∫((Log[1+g((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  ⟶  
-((PolyLog[2,-g((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/(b c-a d))+p r s ∫((PolyLog[2,-g((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/((a+b x) (c+d x)))dx

Program code:

Int[u_*Log[v_]*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  With[{g=Simplify[(v-1)*(c+d*x)/(a+b*x)],h=Simplify[u*(a+b*x)*(c+d*x)]},
  -h*PolyLog[2,1-v]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s/(b*c-a*d) + 
  h*p*r*s*Int[PolyLog[2,1-v]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1)/((a+b*x)*(c+d*x)),x] /;
 FreeQ[{g,h},x]] /;
FreeQ[{a,b,c,d,e,f,p,q,r,s},x] && NeQ[b*c-a*d,0] && IGtQ[s,0] && EqQ[p+q,0]

2:  ∫((Log[i (((j (((g+h x))^t)))^u)] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  when  b c-a d≠0 ∧ p+q==0 ∧ s≠-1

Derivation: Integration by parts

Basis: If  p+q==0, then (((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)/((a+b x) (c+d x)))==(∂_x)(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s+1))/(p r (s+1) (b c-a d)))

Basis: (∂_x)Log[i (((j (((g+h x))^t)))^u)]==((h t u)/(g+h x))

Rule: If  b c-a d≠0 ∧ p+q==0 ∧ s≠-1, then

∫((Log[i (((j (((g+h x))^t)))^u)] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  ⟶  

((Log[i (((j (((g+h x))^t)))^u)] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s+1)))/(p r (s+1) (b c-a d)))-((h t u)/(p r (s+1) (b c-a d)))∫(((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s+1))/(g+h x))dx

Program code:

Int[v_*Log[i_.*(j_.*(g_.+h_.*x_)^t_.)^u_.]*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  With[{k=Simplify[v*(a+b*x)*(c+d*x)]},
  k*Log[i*(j*(g+h*x)^t)^u]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s+1)/(p*r*(s+1)*(b*c-a*d)) - 
  k*h*t*u/(p*r*(s+1)*(b*c-a*d))*Int[Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s+1)/(g+h*x),x] /;
 FreeQ[k,x]] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,p,q,r,s,t,u},x] && NeQ[b*c-a*d,0] && EqQ[p+q,0] && NeQ[s,-1]

3:  ∫((PolyLog[n,g ((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  when  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ p+q==0

Derivation: Integration by parts

Basis: ((PolyLog[n,g ((a+b x)/(c+d x))])/((a+b x) (c+d x)))==(∂_x)((PolyLog[n+1,g ((a+b x)/(c+d x))])/(b c-a d))

Basis: If  p+q==0, then (∂_x)((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)==((p r s (b c-a d))/((a+b x) (c+d x))) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1))

Rule: If  b c-a d≠0 ∧ s∈(SuperPlus[ℤ])∧ p+q==0, then

∫((PolyLog[n,g ((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/((a+b x) (c+d x)))dx  ⟶  
((PolyLog[n+1,g ((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s))/(b c-a d))-p r s ∫((PolyLog[n+1,g ((a+b x)/(c+d x))] ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^(s-1)))/((a+b x) (c+d x)))dx

Program code:

Int[u_*PolyLog[n_,v_]*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  With[{g=Simplify[v*(c+d*x)/(a+b*x)],h=Simplify[u*(a+b*x)*(c+d*x)]},
  h*PolyLog[n+1,v]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s/(b*c-a*d) - 
  h*p*r*s*Int[PolyLog[n+1,v]*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^(s-1)/((a+b*x)*(c+d*x)),x] /;
 FreeQ[{g,h},x]] /;
FreeQ[{a,b,c,d,e,f,n,p,q,r,s},x] && NeQ[b*c-a*d,0] && IGtQ[s,0] && EqQ[p+q,0]

8:  ∫((((a+b Log[c((Sqrt[d+e x])/(Sqrt[f+g x]))]))^n)/(A+B x+C (x^2)))dx  when  C d f-A e g==0 ∧ B e g-C (e f+d g)==0 ∧ n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==2 (e f-d g) Subst[(x/(((e-g (x^2)))^2)) F[-((d-f (x^2))/(e-g (x^2)))],x,((Sqrt[d+e x])/(Sqrt[f+g x]))] (∂_x)((Sqrt[d+e x])/(Sqrt[f+g x]))

Basis: If  C d f-A e g==0 ∧ B e g-C (e f+d g)==0, then (1/(A+B x+C (x^2)))==((2 e g)/(C (e f-d g))) Subst[(1/x),x,((Sqrt[d+e x])/(Sqrt[f+g x]))] (∂_x)((Sqrt[d+e x])/(Sqrt[f+g x]))

Rule: If  C d f-A e g==0 ∧ B e g-C (e f+d g)==0 ∧ n∈(SuperPlus[ℤ]), then

∫((((a+b Log[c((Sqrt[d+e x])/(Sqrt[f+g x]))]))^n)/(A+B x+C (x^2)))dx  ⟶  ((2 e g)/(C (e f-d g))) Subst[∫((((a+b Log[c x]))^n)/x)dx,x,((Sqrt[d+e x])/(Sqrt[f+g x]))]

Program code:

Int[(a_.+b_.*Log[c_.*Sqrt[d_.+e_.*x_]/Sqrt[f_.+g_.*x_]])^n_./(A_.+B_.*x_+C_.*x_^2),x_Symbol] :=
  2*e*g/(C*(e*f-d*g))*Subst[Int[(a+b*Log[c*x])^n/x,x],x,Sqrt[d+e*x]/Sqrt[f+g*x]] /;
FreeQ[{a,b,c,d,e,f,g,A,B,C,n},x] && EqQ[C*d*f-A*e*g,0] && EqQ[B*e*g-C*(e*f+d*g),0]

Int[(a_.+b_.*Log[c_.*Sqrt[d_.+e_.*x_]/Sqrt[f_.+g_.*x_]])^n_./(A_.+C_.*x_^2),x_Symbol] :=
  g/(C*f)*Subst[Int[(a+b*Log[c*x])^n/x,x],x,Sqrt[d+e*x]/Sqrt[f+g*x]] /;
FreeQ[{a,b,c,d,e,f,g,A,C,n},x] && EqQ[C*d*f-A*e*g,0] && EqQ[e*f+d*g,0]

9.  ∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx

1:  ∫(Subscript[RF, x]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  when  b c-a d≠0

Derivation: Algebraic expansion and piecewise constant extraction

Basis: u A==u B+u C-(B+C-A) u

Basis: (∂_x)(p r Log[a+b x]+q r Log[c+d x]-Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])==0

Rule: If  b c-a d≠0, then

∫(Subscript[RF, x]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  ⟶  

p r ∫(Subscript[RF, x]) Log[a+b x]dx+ q r ∫(Subscript[RF, x]) Log[c+d x]dx-(p r Log[a+b x]+q r Log[c+d x]-Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]) ∫(Subscript[RF, x])dx

Program code:

Int[RFx_.*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.],x_Symbol] :=
  p*r*Int[RFx*Log[a+b*x],x] + 
  q*r*Int[RFx*Log[c+d*x],x] - 
  (p*r*Log[a+b*x]+q*r*Log[c+d*x] - Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r])*Int[RFx,x] /;
FreeQ[{a,b,c,d,e,f,p,q,r},x] && RationalFunctionQ[RFx,x] && NeQ[b*c-a*d,0] && 
  Not[MatchQ[RFx,u_.*(a+b*x)^m_.*(c+d*x)^n_. /; IntegersQ[m,n]]]

x:  ∫(Subscript[RF, x]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  when  b c-a d≠0

Derivation: Integration by parts

Basis: (∂_x)Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]==((b p r)/(a+b x))+((d q r)/(c+d x))

Rule: If  b c-a d≠0, let u->∫(Subscript[RF, x])dx, then

∫(Subscript[RF, x]) Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]dx  ⟶  u Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)]-b p r ∫(u/(a+b x))dx-d q r ∫(u/(c+d x))dx

Program code:

(* Int[RFx_*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.],x_Symbol] :=
  With[{u=IntHide[RFx,x]},  
  u*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r] - b*p*r*Int[u/(a+b*x),x] - d*q*r*Int[u/(c+d*x),x] /;
 NonsumQ[u]] /;
FreeQ[{a,b,c,d,e,f,p,q,r},x] && RationalFunctionQ[RFx,x] && NeQ[b*c-a*d,0] *)

2:  ∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  when  s∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  s∈(SuperPlus[ℤ]), then

∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  ⟶  ∫((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s) ExpandIntegrand[(Subscript[RF, x]),x] dx

Program code:

Int[RFx_*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  With[{u=ExpandIntegrand[Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,p,q,r,s},x] && RationalFunctionQ[RFx,x] && IGtQ[s,0]

U:  ∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx

Rule:

∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s)dx  ⟶  ∫(Subscript[RF, x]) ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s) dx

Program code:

Int[RFx_*Log[e_.*(f_.*(a_.+b_.*x_)^p_.*(c_.+d_.*x_)^q_.)^r_.]^s_.,x_Symbol] :=
  Unintegrable[RFx*Log[e*(f*(a+b*x)^p*(c+d*x)^q)^r]^s,x] /;
FreeQ[{a,b,c,d,e,f,p,q,r,s},x] && RationalFunctionQ[RFx,x]

N:  ∫u ((Log[e (((f (v^p) (w^q)))^r)])^s)dx  when  v==a+b x ∧ w==c+d x

Derivation: Algebraic normalization

Rule: If  v==a+b x ∧ w==c+d x, then

∫u ((Log[e (((f (v^p) (w^q)))^r)])^s)dx  ⟶  ∫u ((Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])^s) dx

Program code:

Int[u_.*Log[e_.*(f_.*v_^p_.*w_^q_.)^r_.]^s_.,x_Symbol] :=
  Int[u*Log[e*(f*ExpandToSum[v,x]^p*ExpandToSum[w,x]^q)^r]^s,x] /;
FreeQ[{e,f,p,q,r,s},x] && LinearQ[{v,w},x] && Not[LinearMatchQ[{v,w},x]] && AlgebraicFunctionQ[u,x]

Int[u_.*Log[e_.*(f_.*(g_+v_./w_))^r_.]^s_.,x_Symbol] :=
  Int[u*Log[e*(f*ExpandToSum[v+g*w,x]/ExpandToSum[w,x])^r]^s,x] /;
FreeQ[{e,f,g,r,s},x] && LinearQ[w,x] && (FreeQ[v,x] || LinearQ[v,x]) && AlgebraicFunctionQ[u,x]

x:  ∫((Log[i (((j(((g+h x))^s)))^t)] Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(m+n x))dx

Derivation: Integration by substitution

Basis: F[x]==(1/n) Subst[F[((x-m)/n)],x,m+n x] (∂_x)(m+n x)

Rule:

∫((Log[i (((j(((g+h x))^s)))^t)] Log[e (((f (((a+b x))^p) (((c+d x))^q)))^r)])/(m+n x))dx  ⟶  
(1/n) Subst[∫((Log[i (((j(((-((h m-g n)/n)+((h x)/n)))^s)))^t)] Log[e (((f (((-((b m-a n)/n)+((b x)/n)))^p) (((-((d m-c n)/n)+((d x)/n)))^q)))^r)])/x)dx,x,m+n x]

Program code:

(* Int[Log[g_.*(h_.*(a_.+b_.*x_)^p_.)^q_.]*Log[i_.*(j_.*(c_.+d_.*x_)^r_.)^s_.]/(e_+f_.*x_),x_Symbol] :=
  1/f*Subst[Int[Log[g*(h*Simp[-(b*e-a*f)/f+b*x/f,x]^p)^q]*Log[i*(j*Simp[-(d*e-c*f)/f+d*x/f,x]^r)^s]/x,x],x,e+f*x] /;
FreeQ[{a,b,c,d,e,f,g,h,i,j,p,q,r,s},x] *)